Bir programı kapattıgım zaman otomatik olarak başka bir program açılsın

[Email Bot]

Şimdi ben bir exe dosyası açıyorum basit bir program şöyle maruzatım vardı bu programı kapattıgım zaman otomatık olarak başka bir program açılsın ıstıyorum baska bır program dedıgımde onun gıbı tek exe li basit bir program boyle bir komut olusturulabılırmı saygılar hayırlı haftalar.

[Kayserilifatih]

Zannetmiyorum hiç böyle bir şey denemedim fakat şahsen açık olan bir program kapatıldığında mantıken diğer program başlarsa genelde bilgisayarda virüs var demektir ya da şöyle bir risk de olabilir senin dediğin işlem olursa o zaman sistemde bir virüs olsa bir başlattığın uygulamadan sonra kapatınca diğer başlayan uygulamadaki virüsü göremeyebilirsin o yüzden tavsiye etmem

[TRWE_2012]

Şimdi ben bir exe dosyası açıyorum basit bir program şöyle maruzatım vardı bu programı kapattıgım zaman otomatık olarak başka bir program açılsın ıstıyorum baska bır program dedıgımde onun gıbı tek exe li basit bir program boyle bir komut olusturulabılırmı saygılar hayırlı haftalar.

Bu işlevi sağlayacak basit bir yöntem vardır. İstediğiniz şey, bir .exe dosyası kapanınca başka bir .exe dosyasının otomatik açılması. Bu işlemi aşağıdaki gibi gerçekleştirebiliriz.

Birinci program kapanınca ikinci programı otomatik açma

Örnek komut dosyası içeriği (Not Defteri ile yazılır, .bat olarak kaydedilir):

Kod: Tümünü seç

@echo off
start "" "C:\Program Files\Ornek1\birinci_program.exe"
:kontrol
tasklist | findstr /i "birinci_program.exe" >nul
if errorlevel 1 goto ac
timeout /t 2 >nul
goto kontrol
:ac
start "" "C:\Program Files\Ornek2\ikinci_program.exe"
exit

Komut İçerik Açıklaması :

start komutu :

İlk programı başlatır

tasklist + findstr

İlk programın çalışıp çalışmadığını kontrol eder

timeout /t 2

Her 2 saniyede bir kontrol eder

goto ac

İlk program kapanınca ikinciyi başlatır

[TRWE_2012]

Uygulamalı Bir Örnek :

Kod: Tümünü seç

@echo off
start "" "D:\Program Files (x86)\Notepad2 v4.2.25 TR\Notepad2.exe"
:kontrol
tasklist | findstr /i "Notepad2.exe" >nul
if errorlevel 1 goto ac
timeout /t 2 >nul
goto kontrol
:ac
start "" "D:\Program Files\Notepad3\Notepad3.exe"
exit

Bu bendeki iki ünlü metin editörünün tam yoluna göre.Birinci yazılım açıldıktan sonra kullanıcı , birinci yazılımı kapattığında ikinci yazılım açılacak şekilde kodlandı.

[TRWE_2012]

Not: Bugün formumdayım....!!!

Örnek Uygulama- 2 (.VBS Versiyon)

Kod: Tümünü seç

Set shell = CreateObject("WScript.Shell")
shell.Run """D:\Program Files (x86)\Notepad2 v4.2.25 TR\Notepad2.exe""", 1, False

Do
    WScript.Sleep 2000
Loop Until Not isProcessRunning("Notepad2.exe")

shell.Run """D:\Program Files\Notepad3\Notepad3.exe""", 1, False

Function isProcessRunning(processName)
    Set wmi = GetObject("winmgmts:")
    Set procs = wmi.ExecQuery("Select * from Win32_Process Where Name='" & processName & "'")
    isProcessRunning = (procs.Count > 0)
End Function

Kod Açıklaması :

shell.Run

Notepad2’yi başlatır

Do...Loop

Her 2 saniyede bir "Notepad2.exe" çalışıyor mu diye kontrol eder

Function isProcessRunning

WMI ile çalışan işlemleri tarar

False parametresi

Programları beklemeden (arka planda) çalıştırır

Ekran Görüntüsü :

not:ekran görüntüsünde değiştirilecek yerler sarı renk vugulanmış ve numaralandırılmıştır.

Kullanıcı Tavsiyesi : (TRWE_2012)

Bu yazılımı (metin editörünü) kullanın..Kodlama işinde pek mahir kendisi + yazılımın hiçbir metin editöründe olmayan, yazılımsal bir özelliği var.(söylemiyorum kendiniz yazılımı kurcalayarak keşfedin...Böylesi daha iyidir.Hem yazılımın arayüzüne alışmış olursunuz.O gizli özelliği öğrendiğiniz zaman asla elinizden bırakmayacaksınız Notepad3'ü....)

https://rizonesoft.com/downloads/notepad3/

[hokamuka]

Trwe hocam, Tarik hocamın youtube da bir videosunun altina yorum yapmıştım bu sorum otomatik foruma entegre edilmiş ve çözümü çeşitli şekilde vermişsin yabanci kaynaklarda dahi bulamadim gerçekten çok teşekkür ediyorum sen bir dahisin benim sorunum şöyleydi bir oyunu 800x600 olacak sekilde pencere modunda aciyorum ve malum monitor 1080 çözünürluk olduğu için, oyun çözünürlüğü ekranda küçük kalmasin diye masaüstü çözünürlüğünü de 800 piksele düşürüyordum böylece oyunun pencere modu masaüstü çözünürlüğümle esit oluyordu asil sorun şuydu QRes adlı.bat komutlariyla çalışan ve tek tıkla istediğimiz ekran çözünürlüğüne geçen bir yazilim mevcuttu bende oyunun exesiyle beraber bu qres aracılığıyla vbs komut yazdim tek tikla hem oyun açılıyordu hemde manuel olarak çözünürlüğü değiştirme gereksinimim olmuyordu tikladigim anda scripte hem ekran 800p oluyordu hemde oyunum pencere modunda açılıyordu ama oyundan ciktiktan sonra tekrardan ek olarak 1920x1080 olarak ayarladigim scripte basmak zorunda kaliyordum artık bunada gerek kalmadi sayenizde tek tıkla oyunum açılıyor ekstra olarak masaüstü çözünürlüğüm düşüyor ve oyunumu kapattiktan sonra sayenizde hemen masaustum 1080p eski çözünürlüğüne dönüyor ... Belki çok ufak bişey mis gibi görünebilir ama farklı işlerde var işin içinde hile koruma anti cheat, kernel dll, prio – process priority saver ve bulut tabanlı çalışan ardunio ayni anda tek tikla bir robot gibi çalışmakta şuan ve oyunu kapattigimda hepsi killed :))) saygilarimla -elanur

[TRWE_2012]

Trwe hocam, Tarik hocamın youtube da bir videosunun altina yorum yapmıştım bu sorum otomatik foruma entegre edilmiş ve çözümü çeşitli şekilde vermişsin yabanci kaynaklarda dahi bulamadim gerçekten çok teşekkür ediyorum sen bir dahisin benim sorunum şöyleydi bir oyunu 800x600 olacak sekilde pencere modunda aciyorum ve malum monitor 1080 çözünürluk olduğu için, oyun çözünürlüğü ekranda küçük kalmasin diye masaüstü çözünürlüğünü de 800 piksele düşürüyordum böylece oyunun pencere modu masaüstü çözünürlüğümle esit oluyordu asil sorun şuydu QRes adlı.bat komutlariyla çalışan ve tek tıkla istediğimiz ekran çözünürlüğüne geçen bir yazilim mevcuttu bende oyunun exesiyle beraber bu qres aracılığıyla vbs komut yazdim tek tikla hem oyun açılıyordu hemde manuel olarak çözünürlüğü değiştirme gereksinimim olmuyordu tikladigim anda scripte hem ekran 800p oluyordu hemde oyunum pencere modunda açılıyordu ama oyundan ciktiktan sonra tekrardan ek olarak 1920x1080 olarak ayarladigim scripte basmak zorunda kaliyordum artık bunada gerek kalmadi sayenizde tek tıkla oyunum açılıyor ekstra olarak masaüstü çözünürlüğüm düşüyor ve oyunumu kapattiktan sonra sayenizde hemen masaustum 1080p eski çözünürlüğüne dönüyor ... Belki çok ufak bişey mis gibi görünebilir ama farklı işlerde var işin içinde hile koruma anti cheat, kernel dll, prio – process priority saver ve bulut tabanlı çalışan ardunio ayni anda tek tikla bir robot gibi çalışmakta şuan ve oyunu kapattigimda hepsi killed :))) saygilarimla -elanur

Bu portable yazılımı da kullanabilirsin.Ben kendi donanımında (Lenovo IP Gaming 3 PRO) çok amaçlı kullanmaktayım.

Elinin altında olsun.

[hokamuka]

Aklimda bulunsun tekrar teşekkür ederim şuan hiç bozmayayım tek tıkla 7 8 farklı islem yapıyor

[TRWE_2012]

Aklimda bulunsun tekrar teşekkür ederim şuan hiç bozmayayım tek tıkla 7 8 farklı islem yapıyor

Bu .vbs versiyon üst sürüm versiyon'dur.Tam 2-3 saattir üzerinde uğraştım ama yaptım.

Açıklama :

not: bu forum sitesine ulaşamazsınız, çünkü yerel bilgisayar üzerinde kurulu, sadece çevrimdışı "NOT DEFTERİ" olarak kullanılmaktadır.

Kod: Tümünü seç

' Giriş alma
softwareCount = InputBox("Kaç adet yazılım çalıştırılacak? (örnek: 3)", "Yazılım Sayısı")
If Not IsNumeric(softwareCount) Or softwareCount < 1 Then
    MsgBox "Geçerli bir sayı girilmedi. Çıkılıyor...", vbCritical, "Hata"
    WScript.Quit
End If

timeoutSec = InputBox("Her yazılımın çalışması için maksimum süre (saniye)? (örnek: 30)", "Bekleme Süresi")
If Not IsNumeric(timeoutSec) Or timeoutSec < 1 Then
    MsgBox "Geçerli bir süre girilmedi. Çıkılıyor...", vbCritical, "Hata"
    WScript.Quit
End If

pathsInput = InputBox("Yazılımların tam yolunu girin. Virgülle ayırın:" & vbCrLf & vbCrLf & _
    "Örnek:" & vbCrLf & _
    "D:\Program Files\Notepad3\Notepad3.exe,D:\Program Files (x86)\Notepad2 v4.2.25 TR\Notepad2.exe", _
    "Yazılım Yolları")

softwarePaths = Split(pathsInput, ",")

If UBound(softwarePaths) + 1 <> CInt(softwareCount) Then
    MsgBox "Yazılım sayısı ile yol sayısı uyuşmuyor!", vbExclamation, "Uyarı"
    WScript.Quit
End If

Set shell = CreateObject("WScript.Shell")

For i = 0 To UBound(softwarePaths)
    exePath = Trim(softwarePaths(i))
    If exePath <> "" Then
        exeName = GetExeName(exePath)
        shell.Run """" & exePath & """", 1, False

        timeoutCounter = 0
        Do While isProcessRunning(exeName) And timeoutCounter < (timeoutSec * 1000)
            WScript.Sleep 1000
            timeoutCounter = timeoutCounter + 1000
        Loop

        ' Eğer süre doldu ama işlem hâlâ çalışıyorsa, sonlandır
        If isProcessRunning(exeName) Then
            KillProcess exeName
            MsgBox "Süre dolduğu için " & exeName & " sonlandırıldı.", vbExclamation, "Zaman Aşımı"
        End If
    Else
        MsgBox "Boş bir yol girilmiş. Atlanıyor.", vbExclamation, "Dikkat"
    End If
Next

MsgBox "Tüm yazılımlar başarıyla çalıştırıldı ve süreye göre kontrol edildi.", vbInformation, "Tamamlandı"

Function GetExeName(fullPath)
    parts = Split(fullPath, "\")
    GetExeName = parts(UBound(parts))
End Function

Function isProcessRunning(processName)
    Set wmi = GetObject("winmgmts:")
    Set procs = wmi.ExecQuery("Select * from Win32_Process Where Name='" & processName & "'")
    isProcessRunning = (procs.Count > 0)
End Function

Sub KillProcess(processName)
    Set wmi = GetObject("winmgmts:")
    Set procs = wmi.ExecQuery("Select * from Win32_Process Where Name='" & processName & "'")
    For Each p In procs
        p.Terminate()
    Next
End Sub

Güle güle kullanın....

NOT:

Betiği .vbs şeklinde kayıt ederken Kodlamayı : UTF-8'den ANSI'ye çevirin Türkçe Karakter Sorunu oluşmasın.

[TRWE_2012]

İnternette araştırdım böyle bir betik kodlanmış diye....

Sonuç : YOK...

Yani...;

Bu betik burada ilk defa yayınlanmıştır tarafımdan....!

Sordum farkı

TRWE_2012 farkı'dır

Bu sonuç....!