inputtaki Yazıyı Listeye Aktarmak - Çözüldü

[darendeli]

Kod: Tümünü seç

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIEdit.au3>



    $gui = GUICreate("izledigim Filmler", 615, 438, 192, 124)
    Local $idListview = GUICtrlCreateListView("Filmin Adı                      |   Türü      |    Yayınlanma Yılı         ", 10, 10, 390, 100) ;,$LVS_SORTDESCENDING)
    Local $idItem1 = GUICtrlCreateListViewItem("||", $idListview)
    Local $idItem2 = GUICtrlCreateListViewItem("||", $idListview)
    Local $idItem3 = GUICtrlCreateListViewItem("||", $idListview)
	$Input1 = GUICtrlCreateInput("", 56, 120, 321, 21)
	_GUICtrlEdit_SetCueBanner($Input1, "Film Bilgilerini Yazınız!!!", True)
    GUISetState(@SW_SHOW)
    GUICtrlSetData($idItem2, "||")
    GUICtrlSetData($idItem3, "||")
    GUICtrlDelete($idItem1)
    $buton = GUICtrlCreateButton("Filmi Ekle", 10, 150, 200, 30)
	$buton1 = GUICtrlCreateButton("Filmi Sil", 210, 150, 200, 30)


GUISetState()
While 1
	Switch GUIGetMsg()
		Case -3
			Exit
		Case $buton

	EndSwitch
WEnd

inputa Yazılacak film adı Yayın yılı vs. ekle butonuna Basılınca Listedeki Yerini Almasını istiyorum ve Kayıtlı kalacak nasıl kodlara ihtiyacım var

[anxious]

$okuinput = GUICtrlRead($Input1)
$okuinput değişkenini alıp istediğin yere ekleyebilir istediğin yere kaydedebilirsin

[BlueLife]

@darendeli

Örneğine ek yaptım, incelersin. kolay gelsin...

Kod: Tümünü seç

#include <Array.au3>
Local $FilmListesi[10][4] = [[0, 10]] ;ID, FilmAdı, Türü,Yılı

Local $gui = GUICreate("izledigim Filmler", 615, 438, 192, 124)
Local $idListview = GUICtrlCreateListView("Filmin Adı | Türü | Yayınlanma Yılı ", 10, 10, 390, 100) ;,$LVS_SORTDESCENDING)
Local $Input1 = GUICtrlCreateInput("Deneme", 56, 120, 321, 21)
Local $buton = GUICtrlCreateButton("Filmi Ekle", 10, 150, 200, 30)
Local $buton1 = GUICtrlCreateButton("Filmi Sil", 210, 150, 200, 30)

Local $TmpValue
GUISetState(@SW_SHOW)
While 1
	Switch GUIGetMsg()
		Case -3
			Exit
		Case $buton
			$TmpValue = StringStripWS(GUICtrlRead($Input1), 3)
			If StringLen($TmpValue) > 0 Then
				$FilmListesi[0][0] += 1
				If $FilmListesi[0][0] >= $FilmListesi[0][1] Then
					$FilmListesi[0][1] += 10
					ReDim $FilmListesi[$FilmListesi[0][1]][4]
				EndIf

				$FilmListesi[$FilmListesi[0][0]][1] = $TmpValue
				$FilmListesi[$FilmListesi[0][0]][2] = "Fantastic"
				$FilmListesi[$FilmListesi[0][0]][3] = "2017"
				$FilmListesi[$FilmListesi[0][0]][0] = GUICtrlCreateListViewItem($FilmListesi[$FilmListesi[0][0]][1] & "|" & $FilmListesi[$FilmListesi[0][0]][2] & "|" & $FilmListesi[$FilmListesi[0][0]][3], $idListview)
			EndIf
			_ArrayDisplay($FilmListesi)
		Case $buton1
			$TmpValue = GUICtrlRead($idListview)
			If $TmpValue > 0 Then
				For $I = 1 to $FilmListesi[0][0]
					If $TmpValue = $FilmListesi[$I][0] Then
						GUICtrlDelete($TmpValue)
						_ArrayDelete($FilmListesi,$I)
						$FilmListesi[0][0]-=1
						$FilmListesi[0][1] = UBound($FilmListesi)
					EndIf
				Next
				_ArrayDisplay($FilmListesi)
			EndIf
	EndSwitch
WEnd